post your questions about admin-pro

[unionjack]

try packing the settings folder as a pk3

   so its settings.pk3

[thingshappen]

no its meant to be like that or it wont read the txt files

[unionjack]

If the default settings do not load. Contact me or try including your settings in a pk3 file. I found on one Linux server this was necessary for them to load.

   

   as Elgan says in his instuctions

   i had to do this on my linux server

   what u got to loose it dont take 5min to see

[thingshappen]

the settings do load its just the planes that dont work the game is reading the settings file and all the txt files, must be the server like u said. thx

[dixie265]

Hi all, just wondering with the planes in team mode can the trigger file be changed to have a blue light for allies and red for axis around planes ?? ive managed to do it but as soon as someone uses a plane it reverts back to a red light on both teams and i just dont know enough to work it out? thanks

[Elgan {sfx}]

try this:

   

   

   // 08/12/2005 16:43 Forced player to use pistol before he/she starts to use a plane, this fixed sniper
   
   main local.origin local.team local.scale local.start_pos:
   
      if(level.planes == NIL)
      {
         exec server_planes/setup.scr
      }
   
      if(local.origin==NIL)
      {
         println "no origin"
         end
      }
   
      if(local.scale==NIL)
      {
         local.scale = .2
      }
   
      if(local.start_pos==NIL)
      {
         local.start_pos = local.origin + ( 0 0 500 )
      }
   
      if(local.team == NIL)
      {
         println  "no team"
         local.team = randomint (1) + 1
   
         if(local.team == 0)
         {
            local.team = "axis"
         }
         else
         {
            local.team = "allies"
         }
      }
   
      local.plane = spawn script_model "targetname" ("plane_trigger" + local.team)
   
      if(local.team =="axis")
      {
         local.plane model "vehicles/fockwulffly.tik"
      }
      else
      {
         local.plane model "vehicles/p47fly.tik"
      }
   
      local.plane.origin = local.origin
      local.plane.scale = .1
   
      if(local.team == "axis")
      {
         local.plane light 1 0 0 50
      }
      else
      {
         local.plane light 0 0 1 50
      }
   
      //local.plane notsolid
      local.plane ghost
   
      local.plane.shot = 0
   
      local.plane_trig = spawn trigger_multiple "targetname" ("plane_trigger_fly" + local.team)
      local.plane_trig.origin = local.origin
      local.plane_trig setthread fly
      local.plane_trig setsize ( -40 -40 -40 ) ( 40 40 40 )
      local.plane_trig.plane_scale = local.scale
      local.plane_trig.start_pos = local.start_pos
      local.plane_trig.team = local.team
   
      local.plane_trig_shot = spawn trigger_multiple "spawnflags" "128"  "targetname" ("plane_shottrigger" + local.team)
      local.plane_trig_shot.origin = local.origin
      local.plane_trig_shot setthread shot
      local.plane_trig_shot setsize ( -40 -40 -40 ) ( 40 40 40 )
      local.plane_trig_shot.team = local.team
   
      level waittill spawn
   
      local.i[0] = 0
      local.i[1] = 0
      local.i[2] = 0
   
      local.v[0] = 3
      local.v[1] = 4
      local.v[2] = 5
   
      while(1)
      {
         if(local.minues!=1)
         {
            local.v[0] ++
            local.v[1] ++
            local.v[2] ++
         }
   
         if(local.v[2]==10)
         {
            local.minues=1
         }
   
         if(local.v[2]==3)
         {
            local.minues=0
         }
   
         if(local.minues==1)
         {
            local.v[0] --
            local.v[1] --
            local.v[2] --
         }
   
   
         for(local.p=0;local.p<=10;local.p++)
         {
   
         waitframe
   
            local.i[0] += local.v[0]
            local.i[1] += local.v[1]
            local.i[2] += local.v[2]
   
            if(local.plane.shot==1)
            {
               local.i[0] += local.v[0]
               local.i[1] += local.v[1]
               local.i[2] += local.v[2]
               local.i[0] += local.v[0]
               local.i[1] += local.v[1]
               local.i[2] += local.v[2]
               local.plane light 1 0 1 50
            }
   
            local.plane.angles = ( local.i[0] local.i[1] local.i[2] )
         }
      }
   end
   
   fly:
      local.player = parm.other
   
      if(local.player.flying != 1 &&  local.player.OWNS != 1)
      {
         local.team = parm.other.dmteam
   
         local.use_teams = waitexec global/settings.scr::getcmd "use-teams"
   
         if (local.use_teams  == "1")
         {
            if(self.team != local.player.dmteam)
            {
               local.player iprint "You don't have the training for this aircraft"
               local.plane = waitthread find_trig self.team self
   
               local.plane light 0 1 0 100
               waitframe
   
               if(self.team == "axis")
               {
                  local.plane light 1 0 0 50
               }
               else
               {
                  local.plane light 0 0 1 50
               }
               end
            }
         }
         self nottriggerable
   
         local.player useweaponclass pistol
         wait 1
         local.player.plane_start = self.start_pos
         local.player scale self.plane_scale
         local.player exec server_planes/server_fly.scr
   
         local.trigdelay = waitexec global/settings.scr::getcmd "trig-delay"
         local.trigdelay = int local.trigdelay
   
         local.trig = waitthread find_trig self.team self
         local.trig hide
   
         wait local.trigdelay
   
         local.trig show
         self triggerable
      }
   end
   
   shot:
      local.trig = waitthread find_trig self.team self
      local.trig.shot=1
      wait 1
      local.trig.shot=0
   
      if(self.team == "axis")
      {
         local.trig light 1 0 0 50
      }
      else
      {
         local.trig light 0 0 1 50
      }
   
      end
   end
   
   find_trig local.team local.trig:
   
      for(local.i=1;local.i <=  $("plane_trigger" + local.team).size;local.i++)
      {
         if(local.trig.origin ==  $("plane_trigger" + local.team)[local.i].origin)
         {
            end  $("plane_trigger" + local.team)[local.i]
         }
      }
   
   end
   
   switch__all local.team local.dissable:
   
   
      for(local.i=1;local.i <=  $("plane_trigger_fly" + local.team).size;local.i++)
      {
         if(local.dissable == 1)
         {
            $("plane_trigger_fly" + local.team)[local.i] nottriggerable
            $("plane_shottrigger" + local.team)[local.i] nottriggerable
            $("plane_trigger" + local.team)[local.i] hide
         }
         else
         {
            $("plane_trigger_fly" + local.team)[local.i] triggerable
            $("plane_shottrigger" + local.team)[local.i] triggerable
            $("plane_trigger" + local.team)[local.i] show
         }
      }
   end
   
   from_fly local.team:
   
      thread switch__all local.team 1
   
      while(level.planes[local.team] == level.planes_max[local.team])
      {
         wait 1
      }
   
      thread switch__all local.team
   
   end
   

[dixie265]

Thanks Elgan, That works great now you can see which team it belongs too , i also bumped the color up to 100 to make it stand out thanks again

[Diva]

I have the jetpacks loaded up on the server but it says press "E" and nothing happens wondering does soemthing needed to be edited somewhere what did i do wrong. Thanks. I do see the pack they look cool just need them to work.

   

   Also the mines dont work not sure why i  must have to change somethng else also?

   

   Diva

   

   82.165.235.197 is the IP

   

   thanks

[Elgan {sfx}]

mines and jetpacks dont work at the same time

   

   what game are u running?

   

   SH and BT jet's are broken atm, u have to jump and press use with crouych.

   

   for AA< u jump and press use.

[Diva]

Yes its spearhead damn i wish it worked so far its a really easy to use and cool mod thanks for doing it.

[Elgan {sfx}]

np, and sorry

   

   as soon as i got my tree mod done for christmas, i will do AP.

[click]

On version 1.22 I noticed you cant strafe well anymore with the planes. The last version I used the mg's were very affective, can this be changed back ? Were the bombs radius damage lowered to ?

[Cobra {sfx}]

Hehe you bloodthirsty bugger click

[Elgan {sfx}]

i didnt think i did anyhting ot the planes, check your settings file:

   

   maybe check log also.

   

   

   theere is a few probs with 1.22, will be doing a 1.23 sometime soon, got alot of other stuff taking up my time atm:(

[click]

I upped the radiusdamages >:

   

   

   nuke bombs! Had to take em down a bit though!!!

   

   1.22 seems to be working fine now for me. Cant wait for the newest updates!