Freeze Tag BoobyTrap Dummy

[Cobra {sfx}]

Slim asked for the "Frozen Body" code from Mefys Freezetag, Purple on Xnull ripped it out, ive modified it so you can spawn one on Mohdm4, youll find it on the Bridge ... 1 of 4 random models will be spawned ... beware the BoobyTrap  ;D

Harmless Frozen Body...



However ... as you can see there is an extra BoundingBox around it hehehe ...


Now includes its own kill counter  ;D ...



The code ....

Code (cpp) Select Expand


spawnit:
spawnit:
level.killcount = 0

local.ent = spawn script_model
switch ((randomint 4)+1)
{
case 1:
local.ent model "models/player/american_Ranger.tik"
local.type=1
break

case 2:
local.ent model "models/player/german_wehrmacht_soldier.tik"
local.type=2
break

case 3:
local.ent model "models/player/allied_Manon.tik"
local.type=1
break

case 4:
local.ent model "models/player/german_Panzer_Tankcommander.tik"
local.type=2
break

}
local.ent.origin = ( 53 22 328 ) // On the Bridge on Mohdm4 ;)
local.ent.angle = 88
local.ent notsolid
local.ent scale 1      /////// <<<< change this for scale of model, keep scrolling down to change beams

thread BoobyTrap local.ent// Hehehe

if (local.type==1)
{
local.ent.frozencolor = ( 0 1 0 ) // Green = Allies ... who the hell chose blue? :P
}
else
{
local.ent.frozencolor = ( 1 0 0 ) // Red = Axis
}
local.ent.beams = waitthread spawn_beam_cylinder local.ent.origin 15 local.ent.frozencolor

end local.ent


spawn_beam_cylinder local.origin local.radius local.color:
    local.beams[0] = NIL
    waitthread spawn_doublebeam local.beams (local.origin + ( local.radius 0 0 )) local.color
    waitthread spawn_doublebeam local.beams (local.origin + ( -(local.radius * 0.5) (local.radius * 0.866) 0 )) local.color
    waitthread spawn_doublebeam local.beams (local.origin + ( -(local.radius * 0.5) -(local.radius * 0.866) 0 )) local.color
end local.beams




spawn_doublebeam local.beams local.origin local.color:
    local.pts = waitthread find_beam_endpoints (local.origin + ( 0 0 50 )) -75 45     ///// <<< Change beams size here, the 40, 60 and -50, try halving these, then halve again until you find good one
    local.beams[local.beams.size] = waitthread spawn_beam local.pts[0] local.pts[1] local.color
    if (local.pts[2] != NIL)
    {
        local.beams[local.beams.size] = waitthread spawn_beam local.pts[2] local.pts[3] local.color
    }
end


spawn_beam local.origin local.endpoint local.color:
    local.ent = spawn func_beam
    local.ent.origin = local.origin
    local.ent endpoint local.endpoint
    local.ent minoffset 0.0
    local.ent maxoffset 0.0
    local.ent scale 4.0               /// Also change scale here for beams
    local.ent color local.color
    local.ent alpha 0.5
    local.ent numsegments 1
    local.ent life 0
    local.ent damage $player[1] 0
    local.ent activate
end local.ent

find_beam_endpoints local.center local.start local.end:
    local.top = (local.center + ( 0 0 local.start))
    local.bottom = (local.center + ( 0 0 local.end))
    local.result[0] = (trace local.center local.top 0)
    local.result[1] = (trace local.center local.bottom 0)

    local.offset = local.top[2] - local.result[0][2]
    if (local.offset > 5)
    {
        local.secondbeam = (trace local.top local.center 0)
        if (local.secondbeam != local.center)
        {
            // do a second beam
            local.result[2] = local.top
            local.result[3] = local.secondbeam
        }
    }
end local.result


BoobyTrap local.ent:

spawn trigger_multiple targetname "Boom"
$Boom setsize ( -30 -30 0 ) ( 30 30 90 )
$Boom.origin = local.ent.origin
$Boom message " Its a BoobyTrap ... RUN!!!"
$Boom setthread haha
end

haha:
self waittill trigger

self nottriggerable
parm.other stopwatch 3
self loopsound final_countdown
wait 3
self stoploopsound
self thread spawn_fx2 models/animate/fx_mortar_dirt.tik
radiusdamage self 256 384
wait 1
if (parm.other.health == 0)
{
level.killcount ++
waitthread hudprint ("BoobyTrap Victims:  " + (level.killcount)) 0 1 0"
}
wait 5
self triggerable
end


hudprint local.nstring local.r local.g local.b:

   huddraw_rect 187 140 -84 50 50
   huddraw_color 187 local.r local.g local.b
   huddraw_font 187 "facfont-20"
   huddraw_string 187 local.nstring
   huddraw_align 187 left bottom
   huddraw_alpha 187 1
end


spawn_fx2 local.fx:
local.temp = spawn script_model model local.fx
local.temp.origin = self.origin
local.temp scale 1.1
local.temp anim start
wait 5
local.temp remove
end



[Goober {sfx}]

I love the idea. It sounds cool. Nice work.  ;)

[Cobra {sfx}]

Hope someone adds it to a Freezetag server, see how many people a day it kills lmao

[PacRac {sfx}]

Nice and looking fun mod Cobra  ;). Good Work.

Hope someone adds it to a Freezetag server, see how many people a day it kills lmao

Well Slimbips is already using your mod, he just changed the frozen guy to alarm switch.

Good help there Cobra, sad he never comes here to ask for help,  it was a {SFX} member that helped him on that mod anyway.

[Cobra {sfx}]

Oh its not my mod Pac, he asked on XNull for it, Purple pulled it out of FT and i just added some bits so Slim could see it and edit it easier.

Everyone knows where we are ;)

The script above is different to the one Brian has on Mohaaaa, the above script has a kill counter, the one on Mohaaaa has random teleporters and messages/sounds and uses 2 Dummies. the script above has just one Dummy and its BoobyTrapped.

[Shadow {sfx}]

The script above is different to the one Brian has on Mohaaaa, the above script has a kill counter, the one on Mohaaaa has random teleporters and messages/sounds and uses 2 Dummies. the script above has just one Dummy and its BoobyTrapped.

Oh so on AAAA is not the Boobytrap one? Well you could have told me haha xD
Could you upload the boobytrap one as well then so I can put it on there? Cause it's an awesome idea.

[Cobra {sfx}]

Yeh sure hold on :)

Reminds me of the old Piano mod a guy on .map and myself threw together, we had a health pack near the Church on DM2, when you walked over it 2 church pews dropped on you and the piano sound played, looked like a piano falling on you lol, it had a kill counter too. Think the script is on the old MRU.

[Goober {sfx}]

@Cobra: Is this it?


http://www.old.mods-r-us.net/forums.php?m=posts&p=25599&highlight=PEW#25599

Code (cpp) Select Expand

piano:

local.master = spawn ScriptMaster

local.master aliascache leadinmp1 sound/weapons/explo/Exp_LeadIn_06.wav soundparms 0.8 0.2 0.7 0.5 160 3000 auto loaded maps "m moh obj dm team "
local.master aliascache leadinmp2 sound/weapons/explo/Exp_LeadIn_07.wav soundparms 0.8 0.2 0.7 0.5 160 3000 auto loaded maps "m moh obj dm team "
local.master aliascache leadinmp3 sound/weapons/explo/Exp_LeadIn_08.wav soundparms 0.8 0.2 0.7 0.5 160 3000 auto loaded maps "m moh obj dm team "
local.master aliascache leadinmp4 sound/weapons/explo/Exp_LeadIn_09.wav soundparms 0.8 0.2 0.7 0.5 160 3000 auto loaded maps "m moh obj dm team "
local.master aliascache leadinmp5 sound/weapons/explo/Exp_LeadIn_10.wav soundparms 0.8 0.2 0.7 0.5 160 3000 auto loaded maps "m moh obj dm team "
local.master aliascache leadinmp6 sound/weapons/explo/Exp_LeadIn_11.wav soundparms 0.8 0.2 0.7 0.5 160 3000 auto loaded maps "m moh obj dm team "
local.master aliascache leadinmp7 sound/weapons/explo/Exp_LeadIn_12.wav soundparms 0.8 0.2 0.7 0.5 160 3000 auto loaded maps "m moh obj dm team "
local.master aliascache leadinmp8 sound/weapons/explo/Exp_LeadIn_13.wav soundparms 0.8 0.2 0.7 0.5 160 3000 auto loaded maps "m moh obj dm team "


level.killcount = 0

//Trigger Viewable Object
local.object = spawn script_model
local.object model "models/items/item_100_healthbox.tik" // gotta tempt em with summat hehe ;)
local.object.origin = ( -722.45 -1458.90 -28 )
local.object.angles = ( 0 0 0 )


//Trigger Object
level.trigg = spawn trigger_multiple
level.trigg.origin = ( -722.45 -1458.90 -28.77)
level.trigg setsize ( -20 -20 0 ) ( 20 20 30 )
level.trigg message "Dont Look Up!!!"
level.trigg setthread fallingpiano

end



fallingpiano:

local.player = parm.other
level.trigg nottriggerable
local.crate = spawn script_model
local.crate model "static/piano.tik"
local.crate.origin = ( -722.45 -1458.90 1500 )
local.crate.angles = ( 55 180 0 )
local.crate speed 1050
local.crate dmg 2000
local.crate movedown 1528.77
thread explos
local.crate waitmove
if (local.player.health == 0)
{
level.killcount ++
waitthread hudprint ("Piano Fatalities:  " + (level.killcount) ) .75 .65 .1"
}
local.crate delete
local.crate3 = spawn script_model
local.crate3 model "static/pew_damaged.tik"
local.crate3.origin = ( -722.45 -1458.90 -28.77)
local.crate3.angles = ( 0 0 0 )
local.crate2 = spawn script_model
local.crate2 model "static/pew_damaged.tik"
local.crate2.origin = ( -722.45 -1458.90 -28.77)
local.crate2.angles = ( 0 180 0 )
wait 5
local.crate2 delete
local.crate3 delete
level.trigg triggerable

end

explos:
wait .4
local.hurt = spawn script_origin
local.hurt.origin = ( -722.45 -1458.90 -28.77)
local.explosion = spawn script_model
local.explosion model models/animate/fx_mortar_dirt.tik
local.explosion.origin = ( -722.45 -1458.90 -28.77)
local.hurt playsound leadinmp
wait 1
local.explosion anim start
radiusdamage local.hurt 150 384
wait 4
local.explosion remove
local.hurt remove

end

[Cobra {sfx}]

Yep thats the one haha

[easymeat {sfx}]

now that piano thing is just cool.

[Cobra {sfx}]

Funny as hell to watch ingame lol gotta have some fun eh